CU Amiga Super CD-ROM 2/CU Amiga Magazine's Super CD-ROM 02 (1996)(EMAP Images)(GB)[!][issue 1996-04].iso/magazine/amiga_e/amigae.jan.archive/000035_crash!ifi.uio.no!arvidj_Sun, 16 Jan 94 01:11:41 PST.msg

Text File | 1994-02-17 | 11KB | 378 lines

Received: by bkhouse.cts.com (V1.17-beta/Amiga)
      id <[e-mail]>; Sun, 16 Jan 94 01:11:41 PST
Received: from ifi.uio.no by crash.cts.com with smtp
    (Smail3.1.28.1 #18) id m0pLHGW-0000dqC; Sat, 15 Jan 94 12:06 PST
Received: from sognsvann.ifi.uio.no by ifi.uio.no with ESMTP (8.6.4/ifi2.4)
    id <[e-mail]> for <[e-mail]> ; Sat, 15 Jan 1994 21:06:28 +0100
Received: from localhost by sognsvann.ifi.uio.no ; Sat, 15 Jan 1994 21:06:17 +0100
MIME-Version: 1.0
Message-Id: <[e-mail]>
Date: Sat, 15 Jan 1994 21:06:16 +0100 (MET)
X-Mailer: ELM [version 2.4 PL21]
Content-Type: text
Content-Length: 8090
From: =?iso-8859-1?Q?Arvid_S=F8ndrol_Johansen?=  <[e-mail]>
To: [e-mail] (amigae)
Subject: Image on a (gadtools) gadget.


Does anybody know how to put an image on a (gadtools) gadget? We've
tried something like this:


/*------------------------ START OF SOURCE ------------------------- */

/* An experimental source to get an image on a gadtools gadget -
   does not work!

   The image is a brush of a magnify glass converted to bitmap by a
   program from the stone age - DeLuxeConvert.
*/

ENUM    NONE,
    ER_OPENLIB,
    ER_WB,
    ER_VISUAL,
    ER_CONTEXT,
    ER_GADGET,
    ER_WINDOW,
    ER_MEMORY

MODULE    'intuition/intuition',
    'intuition/gadgetclass',
    'intuition/screens',
    'gadtools',
    'libraries/gadtools',
    'exec/memory'
    'exec/nodes',

DEF    scr=NIL:PTR TO screen,
    wnd=NIL:PTR TO window,
    magnify=NIL:PTR TO gadget,
    picture=NIL:PTR TO image,
    visual=NIL,
    glist=NIL,
    offsety,
    g,
    type,
    infos,
    memblock


PROC main() HANDLE
    openinterface()
    REPEAT
        wait4message()
    UNTIL type=IDCMP_CLOSEWINDOW
    Raise(NONE)
EXCEPT
    closeinterface()
    IF exception>0 THEN WriteF('Could not \s!\n',
        ListItem(['',
            'open "gadtools.library" v37',
            'lock workbench',
            'get visual infos',
            'create context',
            'create gadget',
            'open window',
            'alloc chip memory'],exception))
ENDPROC

PROC openinterface()

/* Prepare everything */

    IF (gadtoolsbase:=OpenLibrary('gadtools.library',37))=NIL THEN Raise(ER_OPENLIB)
    IF (scr:=LockPubScreen('Workbench'))=NIL THEN Raise(ER_WB)
    IF (visual:=GetVisualInfoA(scr,NIL))=NIL THEN Raise(ER_VISUAL)
    offsety:=scr.wbortop+Int(scr.rastport+58)+1
    IF (g:=CreateContext({glist}))=NIL THEN Raise(ER_CONTEXT)

/* Alloc and copy image to chip memory */

    IF (memblock:=AllocMem(128,MEMF_CHIP))=NIL THEN Raise(ER_MEMORY)
    CopyMem({bitmap},memblock,128)

/* Define image structure */

    picture.leftedge:=0
    picture.topedge:=0
    picture.width:=25
    picture.height:=15
    picture.depth:=2
    picture.imagedata:=memblock
    picture.planepick:=NIL
    picture.planeonoff:=NIL
    picture.nextimage:=NIL

/* Define newgadget structure */

    magnify.nextgadget:=0
    magnify.leftedge:=154
    magnify.topedge:=148
    magnify.width:=25
    magnify.height:=15
    magnify.flags:=4
    magnify.activation:=0
    magnify.gadgettype:=1
    magnify.gadgetrender:=picture
    magnify.selectrender:=0
    magnify.gadgettext:=0
    magnify.mutualexclude:=0
    magnify.specialinfo:=0
    magnify.gadgetid:=3
    magnify.userdata:=0

/* Create imagegadget */

    IF (magnify:=g:=CreateGadgetA(BUTTON_KIND,g,
        [154,148,25,15,NIL,NIL,1,0,visual,0]:newgadget,
        [GA_IMAGE,picture,
        NIL]))=NIL THEN Raise(ER_GADGET)

/* Open and refresh window */

    IF (wnd:=OpenW(10,15,200,offsety+165,$304 OR SCROLLERIDCMP,$E,
        'ImageGadget',NIL,1,glist))=NIL THEN Raise(ER_WINDOW)
    Gt_RefreshWindow(wnd,NIL)
ENDPROC

PROC closeinterface()
    IF visual THEN FreeVisualInfo(visual)
    IF wnd THEN CloseWindow(wnd)
    IF glist THEN FreeGadgets(glist)
    IF scr THEN UnlockPubScreen(NIL,scr)
    IF gadtoolsbase THEN CloseLibrary(gadtoolsbase)
ENDPROC

PROC wait4message()
    DEF mes:PTR TO intuimessage,g:PTR TO gadget
    REPEAT
        type:=0
        IF mes:=Gt_GetIMsg(wnd.userport)
            type:=mes.class
            IF (type=IDCMP_GADGETDOWN) OR (type=IDCMP_GADGETUP)
                g:=mes.iaddress
                infos:=g.gadgetid
            ELSEIF type=IDCMP_REFRESHWINDOW
                Gt_BeginRefresh(wnd)
                Gt_EndRefresh(wnd,TRUE)
                type:=0
            ELSEIF type<>IDCMP_CLOSEWINDOW
                type:=0
            ENDIF
            Gt_ReplyIMsg(mes)
        ELSE
            Wait(-1)
        ENDIF
UNTIL type
ENDPROC

/* Include binary file of image (raw bitmap without colour map) from
   hard disk.
*/

bitmap:
INCBIN 'rf:test.bitm'

/*------------------------- END OF SOURCE -------------------------- */


This source gives us a window with an empty gadget - no image!
We've also tried AddGadget(), but can't get the gadget on the screen
at all. Most of the times a pattern appeared, the screen got black,
and the Amiga crashed without any warnings (sometimes we got guru
number 81000005 or 8100000B).

Can anybody help us with this problem?


In Karl-Erik's experiments with INCBIN, he also discovered how to
include an IFF file into a program and show it with iff.library:


/*------------------------ START OF SOURCE ------------------------- */

/*
   Example for including an IFF ILBM-picture into your code and display
   it. Source made by Karl-Erik Ruud.
   This source is based on an iff.library source posted here earlier
   (by Dave Higginson I think - please correct me if I'm wrong!)

   It is not neccesary to use IfFL_OpenIff().

   Change the name of the bitmap (at the end of the source) to your own
   picture path and name.
*/


MODULE    'iff',            /* Iff library funtions and registers */
    'libraries/iff',    /* Iff library header */
    'intuition/intuition',    /* Intuition header */
    'intuition/screens',    /* Screen types and flags */
    'exec/memory',        /* Memory flags */
    'graphics/display'    /* Display modes for screen */

ENUM    ER_NONE,        /* No error */
    ER_IFFLIB,        /* No iff-library */
    ER_OPENIFF,        /* Could not open iff */
    ER_NOBMHD,        /* No bitmap header (dimmensions) */
    ER_SCREEN,        /* Could not open screen */
    ER_WINDOW,        /* Could not open window */
    ER_DECODE        /* Could not decode picture */

DEF    s=NIL,            /* Screen */
    ct[256]:ARRAY OF INT,    /* Colour table (up to 256 colours) */
    bmhd,            /* Bitmap header (width (bmhd), height (bmhd+2), depth (bmhd+8)) */
    w=NIL:PTR TO window,    /* Pointer to window */
    quit=FALSE,        /* Variable to decide if the user quit */
    msg:PTR TO intuimessage, /* Pointer to intuition message */
    sprite=NIL,        /* Invisible sprite data */
    viewmode=NIL        /* Viewmode (f.ex. HOLDANDMODIFY+INTERLACE) */


PROC main() HANDLE

/* Open iff.library  */

    IF (iffbase:=OpenLibrary('iff.library',21))=NIL THEN Raise(ER_IFFLIB)

/* BMHD = BitMap Header (contains dimensions of picture)
   bmhd=picturewidth
   bmhd+2=pictureheight
   bmhd+8=number of bitplanes
*/

    IF (bmhd:=IfFL_GetBMHD({bitmap}))=NIL THEN Raise(ER_NOBMHD)

/* If no viewmode info in file, calculate it (a hack that fails sometimes) */

    IF (IfFL_FindChunk({bitmap},'CAMG'))=NIL
        IF Int(bmhd)>=640
            viewmode:=MODE_640
        ELSEIF Int(bmhd)<640
            viewmode:=0
            IF Char(bmhd+8)=6 THEN viewmode:=viewmode+$800
        ENDIF
        IF Int(bmhd+2)>300 THEN viewmode:=viewmode+INTERLACE
    ELSE
        viewmode:=IfFL_GetViewModes({bitmap})
    ENDIF

/* Open screen with correct dimensions */

    IF (s:=OpenScreenTagList(NIL,
        [SA_WIDTH,Int(bmhd),
         SA_HEIGHT,Int(bmhd+2),
         SA_DEPTH,Char(bmhd+8),
         SA_DISPLAYID,viewmode,
         SA_TYPE,PUBLICSCREEN,
         0,0]))=NIL THEN Raise(ER_SCREEN)

/* Open a window based on the pictures dimmensions */

        IF (w:=OpenWindowTagList(NIL,
        [WA_LEFT,0,
         WA_TOP,0,
         WA_WIDTH,Int(bmhd),
         WA_HEIGHT,Int(bmhd+2),
         WA_FLAGS,WFLG_SIMPLE_REFRESH OR WFLG_NOCAREREFRESH OR WFLG_BORDERLESS OR WFLG_ACTIVATE,
         WA_IDCMP,IDCMP_MOUSEBUTTONS OR IDCMP_RAWKEY,
         WA_PUBSCREEN,s,
         NIL,NIL]))=NIL THEN Raise(ER_WINDOW)

/* Blank the mouse pointer */

    IF sprite:=AllocMem(20,MEMF_CHIP OR MEMF_CLEAR)
        SetPointer(w,sprite,1,16,0,0)
    ENDIF

/* Set the palette of the screen */

    LoadRGB4(s+44,ct,IfFL_GetColorTab({bitmap},ct))

/* Try to load the picture */

    IF (IfFL_DecodePic({bitmap},s+184))=FALSE THEN Raise(ER_DECODE)

/* Wait for the user to press the mouse or a button */

    REPEAT
        IF msg:=GetMsg(w.userport)
            quit:=(msg.class AND (IDCMP_MOUSEBUTTONS OR IDCMP_RAWKEY))
        ELSE
            quit:=(Wait(-1) AND Shl(1,12))
        ENDIF
    UNTIL quit
    Raise(ER_NONE)        /* Do not give any error */
EXCEPT                /* Handle expections */

/* Clean up */

    IF w THEN CloseWindow(w)
    IF sprite THEN FreeMem(sprite,20)
    IF s THEN CloseScreen(s)
    IF iffbase THEN CloseLibrary(iffbase)

/* Display possible error message */

    IF exception>0
        WriteF('Error: \s.\n',
            ListItem(['',
                  'No IFF library version >21',
                  'Could not open IFF file',
                  'IFF File had no bitmap header',
                  'Could not open screen',
                  'Could not open window',
                  'Could not decode picture'],
                exception))
    ENDIF
ENDPROC

/* Include an IFF image in the code - replace this with your own */

bitmap:

INCBIN 'dh0:pictures/Babylon5.iff'

/*------------------------- END OF SOURCE -------------------------- */



                       >>>-- Arvid --> and K-E

(Hope this came correctly through...)
From crash!hermes.cam.ac.uk!dmh1002 Mon, 17 Jan 94 01:06:38 PST
Received: by bkhouse.cts.com (V1.17-beta/Amiga)
      id <[e-mail]>; Mon, 17 Jan 94 01:06:38 PST
Received: from ppsw2.cam.ac.uk by crash.cts.com with smtp
    (Smail3.1.28.1 #18) id m0pLX5Q-0000dRC; Sun, 16 Jan 94 05:00 PST
Received: from black.csi.cam.ac.uk by ppsw2.cam.ac.uk
          with SMTP-CAM (PP-6.0) as ppsw.cam.ac.uk
          id <[e-mail]>; Sun, 16 Jan 1994 13:00:02 +0000
Received: from hermes.cam.ac.uk by black.csi.cam.ac.uk
          id <[e-mail]>; Sun, 16 Jan 1994 12:59:54 +0000
Date: Sun, 16 Jan 1994 13:01:02 +0000 (GMT)
In-Reply-To: <[e-mail]>
Message-ID: <[e-mail]>
MIME-Version: 1.0
Content-Type: TEXT/PLAIN; charset=US-ASCII
Sender: [e-mail]
From: Dave Higginson <[e-mail]>
To: The AmigaE Mailing List <[e-mail]>
Subject: Re: Image on a (gadtools) gadget.


You're not allowed to modify a GadTools gadget using your own image
rendering, and I would guess that the button gadget does not recognise the
GA_IMAGE tag. Your best bet would be to use a GENERIC_KIND gadget with
your own rendering. The Libraries RKM describes how to do this.

Cheers
Dave Higginson

And yes, I did post the iff source :-)

P.S. It's nice to be back. I see that Norm's changed to a listserv
system. I had major problems subscribing last year between September and
November because I could not get any mail through to Norm.